source: 2016/koodauskerho/VilleH/Untitled.scad @ 8415

// Mario Box template for OpenSCAD
// (C) Copyright 2011, Brian Enigma <brian@netninja.com>
// [http://netninja.com/fun/mariobox]
//
// Licensed under a Creative Commons Attribution, Non-Commercial, Share-Alike license.
// For the detailed license, see [http://creativecommons.org/licenses/by-nc-sa/3.0/]
// 
// This file is for feeding into OpenSCAD to produce an STL file
// for 3D printing.  For more information about OpenSCAD, see [http://www.openscad.org/]
//

pixels = [
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 
0, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 0, 0, 0, 
0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 
0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 
0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 0, 1, 1, 1, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 
0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 
0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 
];


pixelCountX = 14;
pixelCountY = 14;

EDGE_LENGTH = 50;               // 5cm cube
BOTTOM_THICKNESS = (0.4 * 3);   // about 3 layers on the bottom
WALL_THICKNESS = 2;             // 2mm wall
COLUMN_LENGTH = 4;              // corner support column
PIXEL_SPACING_ADJUSTMENT = 2;   // Make this bigger to make the pixels smaller, but the space between pixels larger

PIXEL_WIDTH = (EDGE_LENGTH - COLUMN_LENGTH * 2) / (pixelCountX + PIXEL_SPACING_ADJUSTMENT);
PIXEL_HEIGHT = PIXEL_WIDTH; // (EDGE_LENGTH - BOTTOM_THICKNESS * 2) / (pixelCountY + PIXEL_SPACING_ADJUSTMENT);
PIXEL_GRID_WIDTH = (EDGE_LENGTH - COLUMN_LENGTH * 2) / pixelCountX;
PIXEL_GRID_HEIGHT = PIXEL_GRID_WIDTH; // (EDGE_LENGTH - BOTTOM_THICKNESS * 2) / pixelCountY;

difference()
{
    union() // Box body (sides, bottom, support columns)
    {
        // Bottom
        translate(v = [EDGE_LENGTH / -2, EDGE_LENGTH / -2, 0])
            cube(size = [EDGE_LENGTH, EDGE_LENGTH, BOTTOM_THICKNESS]);
        // Corner support columns
        for (i = [0 : 90 : 270])
            rotate(a = i, v = [0, 0, 1])
                translate(v = [EDGE_LENGTH / 2 - COLUMN_LENGTH, EDGE_LENGTH / 2 - COLUMN_LENGTH, 0]) // center it
                    cube(size = [COLUMN_LENGTH, COLUMN_LENGTH, EDGE_LENGTH]);
        // Walls
        for (i = [0 : 90 : 270])
            rotate(a = i, v = [0, 0, 1])
                translate(v = [EDGE_LENGTH / 2 - WALL_THICKNESS, EDGE_LENGTH / -2, 0])
                    cube(size = [WALL_THICKNESS, EDGE_LENGTH, EDGE_LENGTH]);
    }
    for (i = [0 : 90 : 270]) // Apply pixel grid to all four sides
    {
        rotate(a = i, v = [0, 0, 1]) // Rotate to side
        {
            translate(v = [PIXEL_GRID_WIDTH * pixelCountX / -2, EDGE_LENGTH / -2 + WALL_THICKNESS + 2, (EDGE_LENGTH - (PIXEL_GRID_HEIGHT * pixelCountY)) / 2]) // Move over, centered on wall
            {
                rotate(a = 90, v = [1, 0, 0]) // Stand it upright
                {
                    union() // These are the pixels
                    {
                        for (posX = [0 : pixelCountX - 1])
                        {
                            for (posY = [0 : pixelCountY - 1])
                            {
                                if (pixels[((pixelCountY - 1) - posY) * pixelCountX + posX] == 1)
                                {
                                    translate(v = [PIXEL_GRID_WIDTH * posX, PIXEL_GRID_HEIGHT * posY, 2.8])
                                        cube(size = [PIXEL_WIDTH, PIXEL_HEIGHT, WALL_THICKNESS * 4]);
                                }
                            }
                        }
                    }
                }
            }
        }
    }
}