source: 2010/24/build_games.bat @ 1690

@echo off
setlocal
rem | Compiles all the students' games.
rem | The students' directories should be the subdirectories of
rem | the current directory.

set DefaultFrameworkDir=%WINDIR%\Microsoft.NET\Framework

if not defined FrameworkDir (
   set FrameworkDir=%DefaultFrameworkDir%
)

if not exist %FrameworkDir%\v3.5 (
  ECHO.
  ECHO.
  echo .NET Framework 3.5 required.
  ECHO.
  ECHO.
  goto end
)

set msbuild=%FrameworkDir%\v3.5\MSBuild.exe

if not exist lib\jypeli2.dll (
  echo lib path expected which contains jypeli2.dll
  goto end
)

set root=%CD%
set pelit=%root%\pelit
set lib=%root%\lib
set build=%msbuild% /t:Build /p:Configuration=Release /p:"ReferencePath=%lib%"
set copy_dir=xcopy /S /Q /I /Y

if exist %pelit%\NUL rd /S /Q %pelit%
mkdir %pelit%

for /D %%d in (*) do (

  mkdir "%pelit%\%%d"

  for /D %%e in (%%d\*) do (
    pushd %%e

    for %%p in (*.csproj) do (
      rem | We have at least one project file in the directory,
      rem | let's build it.

      %build% "%%p" > NUL

      if errorlevel 1 (
        echo DOES NOT BUILD: %%e
      )

      rem We don't need these.
      if exist "bin\x86\Release\*.pdb" del /F /Q "bin\x86\Release\*.pdb"
      if exist "bin\x86\Release\Jypeli2.xml" del /F /Q "bin\x86\Release\Jypeli2.xml"

      %copy_dir% bin\x86\Release "%pelit%\%%e" > NUL
    )

    rem | In case someone has "Create directory for solution" set
    for /D %%f in (*) do (
      pushd %%f

      for %%p in (*.csproj) do (
        %build% "%%p" > NUL

        if errorlevel 1 (
          echo DOES NOT BUILD: %%e
        )

        rem We don't need these.
        if exist "bin\x86\Release\*.pdb" del /F /Q "bin\x86\Release\*.pdb"
        if exist "bin\x86\Release\Jypeli2.xml" del /F /Q "bin\x86\Release\Jypeli2.xml"

        %copy_dir% bin\x86\Release "%pelit%\%%e" > NUL
      )

      popd
    )

    popd
  )
)

echo.
echo Tehtiin hakemisto pelit

:end
endlocal